MyIcon  ICON  IconMy.ico
12  ICON  aIcon.ico

MyDialog DIALOG  12, 10, 206, 86
   STYLE WS_POPUP | WS_DLGFRAME | WS_CAPTION
   CAPTION " A Dialog Form"
   FONT 10, "MS Sans Serif"
   {
   LTEXT "Simple Dialog"  200, 8, 6, 196, 8
   PUSHBUTTON "OK"   IDOK, 48, 71,  32, 12
   }

DEFPUSHBUTTON "Cancel" IDCANCEL, 8, 67,  32, 12
PUSHBUTTON "a Button"   501, 108, 71,  44, 12,
LTEXT "Static Text Left aligned"  201, 5, 21, 196, 24
CTEXT "Static Text Centered"     202, 18, 12, 170, 8
RTEXT "Static Text Right Aligned"     203, 9, 25, 100, 8
ICON  "IconResName" -1, 1,1,0,0
EDITTEXT 300, 9, 47, 180, 50, ES_MULTILINE, WS_EX_CLIENTEDGE
CHECKBOX "Check Box", 100, 10, 60, 69, 8
AUTOCHECKBOX "Auto CheckBox", 101, 140, 60, 61, 8
RADIOBUTTON "radio", 400, 8, 32, 64, 8
AUTORADIOBUTTON "needs WS_GROUP", 401, 8, 42, 64, 8, WS_GROUP
GROUPBOX "GroupBox", -1, 4,22,150,42
SCROLLBAR 600, 4, 38, 180, 8, SBS_HORZ
COMBOBOX  703, 2, 2, 110, 10, WS_CLIPSIBLINGS

var
DialogUnits: Cardinal;
Xpixel, Ypixel, Xdialog, Ydialog: Integer;
begin
DialogUnits := GetDialogBaseUnits;
Xdialog := 120;
Ydialog := 92;
Xpixel := Round((Xdialog * LOWORD(DialogUnits)) / 8);
Ypixel := Round((Ydialog * HIWORD(DialogUnits)) / 4);

Xpixel := 74;
YPixel := 20;
Xdialog = Round((Xpixel * 4) / LOWORD(DialogUnits);  
Ydialog = Round((Ypixel * 8) / HIWORD(DialogUnits);
end;

function DialogBox(hInstance: HINST; lpTemplate: PChar;
      hWndParent: HWND; lpDialogFunc: TFNDlgProc): Integer;

BOOL DlgProc(HWND hwndDlg; UINT message; 
             WPARAM wParam; LPARAM lParam);

Pascal -

function DlgProc(hwndDlg, message: Cardinal; 
                 wParam, lParam: Integer): BOOL;

NOTE -The DialogProc Result is a 4 byte BOOL type, However this seems to be left over from 16-bit Windows, the System seems to read this as an Integer, and Should be an Integer Type for 32-Bit Pascal, the same as used in the Window Proc Result. For this first example program, I will change this to an Integer type, and Setting the Result to Zero for False and to Any number above Zero for True (One). . .

function DlgProc(hwndDlg, message, wParam, lParam: Integer): Integer;

function EndDialog(hDlg: HWND; nResult: Integer): BOOL;

program Dialogs;
{this program will use DialogBox function to create a
templete Dialog Box, The resource templete for the dialog
is in the Dlg1.RES resource}

uses
  Windows, Messages, smallUtils;

{$R *.RES}
{$R Dlg1.RES} // Include dialog resource

var
wClass: TWndClass;
hForm1, Font1, hLabel3, Brush1: Integer;
mainMsg: TMSG;
Rect1: TRect;
DlgText, DlgEditText: String;
DlgChk, Dlg2Chk: Boolean;

const
{because there are so many zeros, I set a constant as a Zero value}
Zero = 0;
{I give the three buttons on the main Form ID numbers as constants}
ID_EXIT = 100;
ID_ShowDlg = 101;
ID_DlgCB = 102;
ID_Edit1 = 303;

{- - The Result of this DialogProc is listed
as Type BOOL, a 4 byte Boolean value, , , However this seems to be left over
from 16-bit windows, the system seems to read this as an Integer, and use
this function just like the WindowProc (MessageProc), where you can pass
integers as the Result, see the  WM_CTLCOLORDLG  message below}
function DialogProc(hWnd, Msg, wParam, lParam:Integer): Integer{BOOL}; stdcall;
{this is the Message Proc for the Dialog Box. Some of the messages
here are like WndProc (MessageProc) messages (WM_COMMAND, WM_CLOSE)
and othes (WM_INITDIALOG, WM_CTLCOLORDLG) are not. In a Dialog Proc 
a DlgItem ID is often used instead of a hWnd}
var
OKrect:TRect;
Buffer: Array[Zero..255] of Char;
begin
Result := Zero {False};
case Msg of
  WM_INITDIALOG: begin
{WM_INITDIALOG is where you set your Dlg Items properties. There are
special DlgItem functions (SendDlgItemMessage, SetDlgItemText) to help
with this.}
               DlgEditText := '';
               SendMessage(hWnd, WM_SETICON, 1, LoadIcon(hInstance,'Z1'));
         {a default Icon is used in Dialogs, you should set the Icon}
               SendDlgItemMessage(hWnd,200,WM_SETFONT,Font1, Zero);
         {SendDlgItemMessage uses an ID number instesd of hWnd}
               CheckDlgButton(hWnd,100,BST_CHECKED);
               
    {NOTICE - that the next IsDlgButtonChecked function has the hForm1 and
     NOT the hWnd, this gets the Check State of the checkBox on the Main Form,
     NOT on the Dialog Box, this is to show you that the Dialog functions can
     be used with non-dialog windows}
               if IsDlgButtonChecked(hForm1, ID_DlgCB) = BST_CHECKED then
               //if SendMessage(hCheckCB,BM_GETCHECK,0,0) = BST_CHECKED then
                 begin
                 {you can get info from your main Form to set Dialogs}
                 SetWindowText(GetDlgItem(hWnd,201),'Checkbox is Checked');
           { you could use the SetWindowText, but SetDlgItemText does the same
             SetDlgItemText(hWnd,201,'Checkbox is Checked');}
                 EnableWindow(GetDlgItem(hWnd,101),False);
                 {most of the change Window functions will work in Dialogs}
                 end;
               {SetWindowText(GetDlgItem(hWnd,202),PChar(DlgText));}
               SetDlgItemText(hWnd,202,PChar(DlgText));
               GetDlgItemText(hForm1, ID_Edit1, Buffer, 256);
               SetDlgItemText(hWnd,300,Buffer);
               GetWindowRect(GetDlgItem(hWnd,IDOK),OKrect);
               SetCursorPos(OKrect.Left+10,OKrect.Top+10);
               end;
  WM_COMMAND: begin
{like the WM_COMMAND in MessageProc, but the wParam may be used instead
of the LParam, you can get the ID number of the control, instead of it's
Handle}
            if LOWORD(wParam) = IDOK then
              begin
              {Dialogs use DlgItem ID's in the LOWORD(wParam)}
              if (IsDlgButtonChecked(hWnd,101) = BST_CHECKED) then
              Dlg2Chk := True;
              if (IsDlgButtonChecked(hWnd,100) = BST_CHECKED) then
                begin
                MessageBox(hWnd,'Dialog Checkbox was checked',
                  'Dialog exit',MB_OK or MB_ICONQUESTION);
                DlgChk := True;
                end;
              DlgEditText := GetWindowStr(GetDlgItem(hWnd,300));
    {unlike MessageProc you use EndDialog to kill a Modal Dialog}
              EndDialog(hWnd, IDOK);
              Result := 1{True};
    {You need to set the Result to One when you call EndDialog}
              end else
              if LOWORD(wParam) = 401 then
              SetDlgItemText(hWnd,300, 'New Edit Text')
              else
              if LOWORD(wParam) = 101 then
              MessageBox(hWnd,'Dialog Checkbox was clicked',
                  'Click It',MB_OK or MB_ICONQUESTION);
            end;
  WM_CLOSE:
    begin
{unlike MessageProc you use EndDialog to kill a Modal Dialog}
    EndDialog(hWnd, IDCANCEL);
    Result := 1 {True};
    end;
  WM_CTLCOLORDLG: Result := Brush1;
{this WM_CTLCOLORDLG is sent to the Dialog's DialogProc and you set the
Result to the color brush used to do the WM_ERASEBKGND message.
You can Leave this message out to get the normal button face color.
This message is rarely used in dialogs and I used it just to show you how}
  WM_CTLCOLORSTATIC:
    begin
    SetBkColor(wParam, $FFFFCC);
    Result := Brush1;
    end;
end;

{You do NOT call any Default message handling for a DialogProc.
You do not Call DefWindowProc( ) or CallWindowProc( ), the default message
handling will be called if you have the Result as Zero}
end;

procedure DoDialog;
var
Dsize: TdriveSize;
begin
if hLabel3 <> Zero then
  begin
{hLabel3 is created according to the check box on the Dialog Box}
  DestroyWindow(hLabel3);
  while PeekMessage(mainMsg, Zero, Zero, Zero, PM_REMOVE) do
  DispatchMessage(mainMsg);
  hLabel3 := Zero;
  end;
Dsize := DiskSpace('C:\');
DlgText := 'C drive''s Total capacity is '+Int2Str(Dsize.TotalS)+
           ' bytes - And it''s free space is '+ Int2Str(Dsize.FreeS);
{DlgText is used in a Static Text control in the Dialog, you should set all
the variables needed for a dialog before you call DialogBox( )}

{DialogBox will create a Modal Dialog from the Resource DIALOG of 'First',
with hForm1 as Parent, and the DialogProc as the WndProc (MessageProc)}
if DialogBox(hInstance, 'First', hForm1, @DialogProc) = IDCANCEL then
  begin
  {the DialogBox function will return the integer used in the EndDialog
  function, which will close this dialog box}
  MessageBox(hForm1,'Dialog was CANCELED',
      'a Dialog result',MB_OK or MB_ICONINFORMATION);
  Exit;
  end;

if DlgChk then
MessageBox(hForm1,'This is DlgChk = True',
      'a Dialog result',MB_OK or MB_ICONQUESTION);
      
if Dlg2Chk then
  begin
{the Dlg2Chk comes from the OK button click on the Dialog Box
and will create a Static Label here}
  hLabel3 := CreateWindow('Static', 'that Check me was Checked',
         WS_VISIBLE or WS_CHILD or SS_CENTER, 6, 200, 300, 29,
         hForm1, Zero, hInstance, nil);
  SendMessage(hLabel3, WM_SETFONT, Font1, Zero);
  end;

SetDlgItemText(hForm1, 201, @DlgEditText[1]);
{instead of SetWindowText, I use SetDlgItemText, with the ID set as 201
which is the second Static (Label) control}
DlgChk := False;
Dlg2Chk := False;
end;

function MessageProc(hWnd,Msg,wParam,lParam:Integer):Integer; stdcall;
begin
{this MessageProc uses ID numbers instead of Handles in the WM_COMMAND
message, just like is used in the DialogProc}
case Msg of
    WM_COMMAND: if LOWORD(wParam) = ID_EXIT then
       PostMessage(hForm1,WM_CLOSE, Zero, Zero)
       else if LOWORD(wParam) = ID_ShowDlg then DoDialog;

    WM_DESTROY: PostQuitMessage(Zero);
end; // case
Result := DefWindowProc(hWnd,Msg,wParam,lParam);
end;


begin  //  MAIN BEGIN / / / / / / / / / / / / /
DlgChk := False;
Dlg2Chk := False;
hLabel3 := Zero;
Brush1 := CreateSolidBrush($FFFFCC);

Font1 := CreateFont(-18, Zero, Zero, Zero, FW_BOLD, Zero, Zero,
                    Zero, ANSI_CHARSET,OUT_DEFAULT_PRECIS, CLIP_DEFAULT_PRECIS,
                    DEFAULT_QUALITY, VARIABLE_PITCH or FF_SWISS,'Arial');

with wClass do
  begin
    style :=        CS_PARENTDC or CS_BYTEALIGNWINDOW;
    hIcon :=        LoadIcon(hInstance,'MAINICON');
    hInstance := SysInit.hInstance;
    lpfnWndProc :=  @MessageProc;
    hbrBackground:= COLOR_BTNFACE+1;
    lpszMenuName := nil;
    lpszClassName:= 'Form Class';
    hCursor :=      LoadCursor(Zero, IDC_ARROW);
    cbClsExtra := Zero;
    cbWndExtra := Zero;
  end;

RegisterClass(wClass);

SetRect(Rect1,Zero,Zero,430,240);
if not AdjustWindowRect(Rect1,WS_CAPTION or WS_MINIMIZEBOX or WS_SYSMENU,False)
  then SetRect(Rect1,Zero,Zero,438,268);

hForm1 := CreateWindow(wClass.lpszClassName, 'Doing Dialogs',
    WS_CAPTION or WS_MINIMIZEBOX or WS_SYSMENU,
    (GetSystemMetrics(SM_CXSCREEN) div 2)-200,
    (GetSystemMetrics(SM_CYSCREEN) div 2)-160,
    Rect1.Right-Rect1.Left, Rect1.Bottom-Rect1.Top,
    Zero, Zero, hInstance, nil);

{NOTICE - I create ALL controls here without getting a Handle
for them, Instead I assign them an ID number (200 for this first Static control)
and use that ID number as a "Dialog" control ID}
CreateWindow('Static', 'Dialogs Demo',
       WS_VISIBLE or WS_CHILD or SS_CENTER,8,8,388,22,hForm1, 200,hInstance,nil);
{Instead of using the SendMessage function, I use the SendDlgItemMessage, and use
the ID number of the control, just like is used in a Dialog's box message Proc.
This will work with any window, even if it is NOT a Dialog Box}
SendDlgItemMessage(hForm1, 200, WM_SETFONT, Font1, Zero);

CreateWindow('Static', 'Put the Text you want to see in the dialog below'+
       #10'the Text you put in the Dlg Edit will show here',
       WS_VISIBLE or WS_CHILD or SS_LEFT,10,38,290,28,hForm1, 201,hInstance,nil);
SendDlgItemMessage(hForm1, 201, WM_SETFONT, GetStockObject(ANSI_VAR_FONT), Zero);

CreateWindow('Button','E x i t',
    WS_VISIBLE or WS_CHILD or BS_PUSHBUTTON or BS_TEXT,
    320,200,74,24, hForm1, ID_EXIT, hInstance,nil);
{this Exit Button is created without getting it's Handle, by assigning
an ID number ID_EXIT, I will use that to reference this button}

CreateWindowEx(WS_EX_CLIENTEDGE,'Edit','type here to be in Dlg Edit',
    WS_VISIBLE or WS_CHILD or ES_LEFT or ES_AUTOHSCROLL,
    16,78,410,21,hForm1, ID_Edit1,hInstance,nil);
SendDlgItemMessage(hForm1, ID_Edit1, WM_SETFONT,
                   GetStockObject(ANSI_VAR_FONT), Zero);

CreateWindow('Button','Show Dialog',
    WS_VISIBLE or WS_CHILD or BS_PUSHBUTTON or BS_TEXT,
    30,160,84,24, hForm1, ID_ShowDlg, hInstance,nil);
SendDlgItemMessage(hForm1, ID_ShowDlg, WM_SETFONT,
                   GetStockObject(ANSI_VAR_FONT), Zero);

CreateWindow('Button','Dialog checkbox',
    WS_CHILD or BS_AUTOCHECKBOX or WS_VISIBLE,
    20,130,150,24, hForm1, ID_DlgCB,hInstance,nil);
SendDlgItemMessage(hForm1, ID_DlgCB, WM_SETFONT,
                   GetStockObject(ANSI_VAR_FONT), Zero);


ShowWindow(hForm1, SW_SHOWDEFAULT);
while GetMessage(mainMsg, Zero, Zero, Zero) do
  begin
    TranslateMessage(mainMsg);
    DispatchMessage(mainMsg);
  end;
DeleteObject(Font1);
DeleteObject(Brush1);
DlgText := '';
DlgEditText := '';

end.

CONTROL text, IDnumber, ClassName, style, x, y, width, height, extended-style

The Class Name of the control being defined, such as the Standard Control Classes, but you should probaly use the previous creation methods for Standard Controls -

BUTTON, COMBOBOX, EDIT, LISTBOX, SCROLLBAR, STATIC.

Or some of the "Common Controls", which is more what this creation method was intended for. The following are Text Contants and should not be put in Quotation marks -

TRACKBAR_CLASS, STATUSCLASSNAME, PROGRESS_CLASS, WC_TREEVIEW, WC_COMBOBOXEX, WC_TABCONTROL, TOOLBARCLASSNAME, REBARCLASSNAME, UPDOWN_CLASS, WC_LISTVIEW, WC_HEADER, TOOLTIPS_CLASS, DATETIMEPICK_CLASS, ANIMATE_CLASS

height - Specifies the height of the control. This value must be a Word value in the range 1 through 65,535. The height is in 1/8-character units.

style - Specifies the control styles. Use the bitwise OR ( | ) operator to combine styles. Using this creation method does NOT prevent the Dialog Creation from Ignoring or not using the Styles that it normally does not use.

extended-style - Specifies extended (WS_EX_xxx) styles. You must specify a style in order to give an extended-style.

ComCtrl DIALOG DISCARDABLE 8, 6, 200, 120
     STYLE WS_POPUP | WS_DLGFRAME | WS_CAPTION | WS_SYSMENU
     CAPTION " CommCtrl Dialog Box"
     FONT 10, "MS Sans Serif"
     {
     CTEXT "Some ComCtrls"     200, 41, 3, 119, 10
     CONTROL "", 600, "SCROLLBAR", SBS_HORZ | WS_TABSTOP, 4, 25, 180, 8
     CONTROL "Track Bar" 700, TRACKBAR_CLASS, WS_VISIBLE | TBS_BOTTOM, 4, 40, 180, 16
     CONTROL "Up Down" 800, UPDOWN_CLASS, WS_VISIBLE | UDS_ALIGNRIGHT | UDS_ARROWKEYS, 14, 60, 9, 10
     DEFPUSHBUTTON "OK"   IDOK, 84, 84,  42, 12, WS_TABSTOP
     CONTROL "Status Bar" 900, STATUSCLASSNAME, WS_VISIBLE, 10, 10, 10, 10
     }