Wheelbarrow.inc

//(c) Robert J Becraft.  All Rights Reserved.
#declare WheelbarrowWheel=union{
difference{
cylinder{<0,0,-.061><0,0,.061> .2}
cylinder{<0,0,-.0611><0,0,.0611> .19}
texture{pigment{color Gray40}}
}
difference{ 
cylinder{<0,0,-.061><0,0,.061> .19}
cylinder{<0,0,-.0611><0,0,.0611> .18}
texture{T_Wood1}
}
cylinder{<0,0,-.15><0,0,.15> .05 texture{T_Wood1}}
cylinder{<0,0,-.2><0,0,.2> .01 texture{pigment{color Gray40}}}
#declare C1=0;
#while (C1<180)
cylinder{<0,-.18,0><0,.18,0> .01 texture{T_Wood1 rotate<90,0,0>} rotate<0,0,C1>}
#declare C1=C1+45;
#end
} 

#declare WheelbarrowHandle=union{ 
cylinder{<-.5,0,-.04><-.5,0,.04>.04 texture{T_Wood1 rotate<0,90,0>}}
box{<-.5,-.04,-.04><.75,.04,.04> texture{T_Wood1 rotate<0,90,0>}}
cone{<.75,0,0>.02<1,0,0>.03 texture{T_Wood1 rotate<0,90,0>}}
sphere{<1,0,0>.03 texture{T_Wood1 rotate<0,90,0>}}
}
#declare WheelbarrowCarry=union{
box{<-.4,-.02,-.28><-.35,.36,-.24> texture{T_Wood1 rotate<90,0,0>}}
box{<-.4,-0.2,.24><-.35,.36,.28> texture{T_Wood1 rotate<90,0,0>}}

box{<-.35,0,-.3><-.32,.05,.3> texture{T_Wood1}}
box{<-.35,.06,-.3><-.32,.11,.3> texture{T_Wood1}}
box{<-.35,.12,-.3><-.32,.17,.3> texture{T_Wood1}} 
box{<-.35,.18,-.3><-.32,.25,.3> texture{T_Wood1}} 
box{<-.35,.26,-.3><-.32,.35,.3> texture{T_Wood1}} 

box{<-.31,0,-.3><-.21,.02,.3> texture{T_Wood1}}
box{<-.20,0,-.32><-.10,.02,.32> texture{T_Wood1}}
box{<-.09,0,-.34><.01,.02,.34> texture{T_Wood1}}
box{<.02,0,-.36><.12,.02,.36> texture{T_Wood1}}
box{<.13,0,-.38><.23,.02,.38> texture{T_Wood1}} 
box{<.24,0,-.4><.34,.02,.4> texture{T_Wood1}}

//object{RefusePile translate<-.25,0,0>} 
} 

#declare WheelbarrowF=union{ 
object{WheelbarrowHandle translate<0,0,.25> rotate<0,-10,0>}
object{WheelbarrowHandle translate<0,0,-.25> rotate<0,10,0>}
object{WheelbarrowWheel translate<-.5,-.02,0> } 
box{<-.02,.04,-.25><.03,.15,.25> texture{T_Wood1} translate<-.24,0,0>} 
box{<-.02,.04,-.4><.03,.06,.4> texture{T_Wood1} translate<.34,0,0>} 
object{WheelbarrowCarry translate<.11,.08,0>} 
}

#declare Wheelbarrow=union{
object{WheelbarrowF rotate<0,0,12>}
box{<-.02,.1,-.02><.02,-.45,.02> texture{T_Wood1 rotate<90,0,0>} translate<.34,.1,-.32>}
box{<-.02,.1,-.02><.02,-.45,.02> texture{T_Wood1 rotate<90,0,0>} translate<.34,.1,.32>} 
translate<0,.325,0>
}