hLib := LoadLibrary('MSHTML.DLL');

ShowHTMLDialog := GetProcAddress(hLib, 'ShowHTMLDialog');

function ShowHTMLDialog(
  hwndParent: Cardinal;   // parent's handle
  UrlMnk: IMoniker;       // IMoniker which has the HTML source file
  PvarArgIn: PVariantArg; // Variant address that contains PWChar sent
                          // to dialog
  PWCHOptions: PWChar;    // pointer to WideChar with Dialog Options
  PvarArgOut: PVariantArg // Variant address receives the data placed
                          // in the IHTMLDialog::returnValue
  ): HRESULT; // function Result is an OLE HRESULT (Integer)

• hwndParent -

Handle to the parent of the dialog box, can be zero.

• UrlMnk -

An IMoniker interface containing the URL from which the HTML file for the dialog box is loaded, file can be in app's resources.

• PvarArgIn -

Pointer to a VariantArg record that contains the data sent to the dialog box. The data passed in this VariantArg is placed in the dialog window object's IHTMLDialog::dialogArguments property. This is mostly set as a VT_BSTR, with a PWChar for text the dialog will use for display. This parameter can be set as an empty VariantArg (VT_EMPTY).

• PWCHOptions -

Window options for the dialog box. This parameter can be NIL or the address of a PWChar that contains a combination of values for the Height, Width, Resizable, Help and Center options, each separated by a semicolon  ; .
 POptions := 'dialogHeight:13;dialogWidth:21;resizable:no;help:no;center:yes'

• PvarArgOut -

Pointer to a VariantArg record that contains the data sent from the dialog box when it closes. This VariantArg gets the data that was placed in the dialog window object's IHTMLDialog::returnValue property. This parameter can be an empty VariantArg.

function CreateURLMoniker(
  MkCtx: IMoniker; // moniker to use as the base context, can be NIL
  szURL: PWChar;   // contains the text of URL to be parsed
  out mk: IMoniker // moniker with URL created from MkCtx and szURL.
  ): HResult; // function Result is an OLE HRESULT (Integer)

or

and like this for a resource -

or

  ArugStr := 'HTML Dialog String Data';
  VarArgs.vt := VT_BSTR;  // a PWideChar type
  VarArgs.bstrVal := StringToOleStr(ArugStr);

  uses ActiveX, ComObj, UrlMon;

  procedure TForm1.button_FileHtmlDlgClick(Sender: TObject);
  type
    TShowHTMLDialog = function(hwndParent: Cardinal;
      UrlMnk: IMoniker; PvarArgIn: PVariantArg;
      PWCHOptions: PWChar; PvarArgOut: PVariantArg): HRESULT; stdcall;
  var
    hLib2: Integer;
    ShowHTMLDialog: TShowHTMLDialog;
    URLMoniker: IMoniker;
    VarArgs, VarReturn: TVariantArg;
    ArugStr, UrlStr, Return: String;
    POptions: PWChar;
  begin
    Return := 'ERROR, IE version is Below 4 or does not support HTML '
            + 'dialogs';
    hLib2 := LoadLibrary('MSHTML.DLL');
    if hLib2 <> 0 then
    try
      ShowHTMLDialog := GetProcAddress(hLib2, 'ShowHTMLDialog');
      if Assigned(ShowHTMLDialog) then
        begin
        // The PvarArgIn is used to Pass Data To the HTML Dialog.
        // The VarArgs Variant will be used here as a PWChar, with the
        // ^ being used as a Delimiter for the seven sub Strings, that
        // are sent to the Dialog
        ArugStr := 'HTML Dialog Top Title^This is Information text '
                 + 'passed to the Dialog^Type your Name Below^'
                 + 'Small^Medium^Large^My Size^One size fits all';
        // The first sub string is the dialog Title, the next substring
        // is the text (and HTML) that will be written to the html with
        // JScript  document.write(ArgArray[1]) , notice that I have
        // HTML tags in this Text, this allows you to customize the
        // dialog from your programs data, all of the sub strings that
        // follow are placed in the Combo Box
        VarArgs.vt := VT_BSTR;
        VarArgs.bstrVal := StringToOleStr(ArugStr);

        // the UrlStr is prefixed with the  file://  to signify a disk
        // file, use  res://  to sigify a resource
        UrlStr := 'file://'+ExtractFilePath(ParamStr(0))+'HtmlDlg1.htm';
        // the URLMoniker is set to the URL of the source of the htm
        // file used for the dialog box, it can be a disk file, a
        // program resource, or an Internet file address, if the html
        // file is not found, a blank dialog box is displayed
        OLECheck(CreateURLMoniker(nil, StringToOleStr(UrlStr),
          URLMoniker));

        POptions := 'dialogHeight:17;dialogWidth:23;resizable:no;'
                  + 'help:no;center:yes';
        // POptions can be omitted (set to nil), but it allows you to
        // set some options of the dialog, like width and height
        VariantInit(OleVariant(VarReturn));
        // VariantInit sets the VarReturn.vt to VT_EMPTY
        if ShowHTMLDialog(Handle, URLMoniker, @VarArgs, POptions,
           @VarReturn) = S_OK then
        begin
          // The JScript  window.returnValue  will automatically set the
          // VarReturn.vt to the data Type that is assigned to it, I only
          // use 2 data types for the window.returnValue  , a JScript
          // text string (VT_BSTR  - OLE wide string) and an integer
          // (VT_I4)  , so any other variant data type will indicate an
          // Error
          if VarReturn.vt = VT_BSTR then
          begin
            Return := VarReturn.bstrVal;
            // I use a  ^  to delimit the VarReturn.bstrVal, but the
            // first Char is the Radio Box number, which is below 9, so
            // I do not delimit it, since it will always be a single
            // Char Return[1]
            Return := 'OK was Clicked'#10'Radio was '+Return[1]+#10
                    + 'Combo1 was '+Copy(Return,2,Pos('^',Return)-2)
                    + #10'Edit Text was  '
                    + Copy(Return,Pos('^',Return)+1, 512);
          end else
            if VarReturn.vt = VT_I4 then
              Return := 'OK was NOT clicked'#10'the VarReturn is '
                      + IntToStr(VarReturn.lVal)
            else
              Return := 'Variant Data type is not integer or OLE '
                      + 'string, ERROR';
        end else
          Return := 'The ShowHTMLDialog FAILED';
      end;
    finally
      FreeLibrary(hLib2);
    end;
    ShowMessage(Return);
  end;

The HTML window.dialogArguments is your access to the data passed to the dialog box. You will usually pass a Wide String or an Integer in your VarArgs parameter to the dialog box. If you want more than one data item in your VarArgs variant, you can use a delimited string and the Split method in

The Split function will use it's single parameter as the delimiter charater, to divide up the string into an array. The only data that ShowHTMLDialog gets from the dialog box comes in the VarReturn (window.returnValue) variant that is passed back as the PvarArgOut parameter. If you need more than one data item returned, you can again use a delimited string, as I have done here.

<html id=dlg1 style="width: 25.9em; height: 22em">
  <!-- If you DO NOT use the PWCHOptions in the ShowHTMLDialog, you can
       put dialog window's width and height above -->
  <head>
  <title>HTML Dialog Test</title>

  <script language="JScript">
  var RBnum = 0;

  var ArgArray = new Array();
  // get the dialog arguments into an array with .split and the
  // delimiter
  ArgArray = window.dialogArguments.split("^");

  // the ArgArray check below is not nessary, but allows you to have a
  // Default dialog box with an empty  PvarArgIn  from ShowHTMLDialog
  if (ArgArray.length == 0) {ArgArray[0] = "Dialog Title";}
  if (ArgArray.length == 1) {ArgArray[1] = "No <b>Info</b> Text";}
  if (ArgArray.length == 2) {ArgArray[2] = "None";}

  // the first Array string is the Title// set the default return value
  window.returnValue = 0;

  function StartUp()
  {
  // clear selections in Combo1
  Combo1.options.length = 0;

  // add the ArgArray strings to the Combo1 selections
  var index;
  index = 2;
  // start with index of 2 because the first 2 strings are title and info
  while(index < ArgArray.length)
     {
     var tempOption = new Option(ArgArray[index]);
     Combo1.options[Combo1.options.length] = tempOption;
     index++;
     }

  // set the first Combo1 selection position
  Combo1.options[0].selected = true;
  }

  function OkClick()
  {
  // this return value means that the OK button was clicked
  window.returnValue = RBnum+Combo1.options[Combo1.selectedIndex].text+
                       "^"+Edit1.value;
  // since the window.returnValue is a variant, it can get text or
  // numbers or objects
  // The integer RBnum is automatically converted to text
  // close the dialog window
  window.close();
  }

  function CancelClick()
  {
  // this -1 return value means that the Cancel button was clicked
  window.returnValue = -1;
  window.close();
  }

  function RadioClick(num)
  {
  RBnum = num;
  // check and UnCheck the Radios
  RB1.checked = (num == 0);
  RB2.checked = (num == 1);
  RB3.checked = (num == 2);
  }

  </script>
  </head>
  <!-- IMPORTANT, have a JScript onload in your Body tag 
  to Initialize your variables from the window.dialogArguments -->
  <body onload="StartUp()" BGCOLOR="#A0E2F2" TEXT="Black">
  <center>
  <font size="5"><b>A HTML Dialog Box</b></font>
  <!-- I use Fixed Font sizes because IE may have it's default font
  size as large or small, throwing off your sizing, but you could
  use style sheet settings to define fonts, colors, borders -->
  <font size="3">
  <br><script language="JScript">
  // a very usefull operation - document.write( )
  // the second array string is the INFO text written here
  document.write(ArgArray[1])
  </script>
  <br><input type=text name="Edit1" value="No Name" size="24"
   title="Type your Name Here"><p>
  <table border="2" cellpadding="8" cellspacing="0">
  <tr><td><font size="3"><input type=radio name="RB1" checked=1
     onClick="RadioClick(0)">Howdy<br>
    <input type=radio name="RB2" onClick="RadioClick(1)">Late<br>
    <input type=radio name="RB3" onClick="RadioClick(2)">Goomba</font>
   </td><td><font size="3">Pick your Size - <select
    name="Combo1"></select></font>
   </td></tr></table>
  <P><input type=button value="OK" id="OkBut" onClick="OkClick()"
   title="Click to use the Entries above">
  <input type=button value="Cancel" id="CancelBut"
   onClick="CancelClick()">
  </font></center>
  </body></html>

Using a resource for the HTML file source
You can use the same code above for a program's resource HTML file, except you will need to place a Resource URL Moniker instead of a File Moniker. You must change the UrlStr to

  UrlStr := 'res://' + ExtractFileName(ParamStr(0)+'/#101');
  OLECheck(CreateURLMoniker(nil, StringToOleStr(UrlStr), URLMoniker));

  #define RT_HTML 23
  #define Dlg1 101

  Dlg1 RT_HTML "HtmlDlg1.htm"

  101 23 "HtmlDlg1.htm"

Resource HTML Images - Here is some info for you if you are more experienced in HTML, but I do not think that IE version 4 will do this. . . I think in some sub-version of Internet Explorer Version 5 you can load html Images from an executable resource. To the IMG HTML tag to can have the res:// instead of the file://, and you need to have the executable file name (path) and two number resource ID for the resource with the image file. Maybe like -

<IMG src="file://MyApp.exe/#21/#105">

In your HTML dialog code you might make the first arrArgs array element your program's file name 'MyApp.exe'. And place a jpg or gif image in it's resources. Next have a JavaScript variable and use some code like this -

var Title_Img = '<img src="res://'+arrArgs[0]+'/#701/#201">';

<SCRIPT language="JScript">document.write(Title_Img)</script>

Advanced Methods

For more advanced HTML dialog boxes it is also possible to set up a COM "Interface" IDispatch link between the dialog box and your program, so the dialog box could call code in in your Delphi program through IDispatch. The VarArgs is a TVariantArg type, and has a "Variant Type" of VT_DISPATCH for an IDispatch Interface. However, My JavaScript programming knowledge is not so advanced, I do NOT know of a way to pass an interface reference in the ShowHTMLDialog( ) PvarArgIn parameter, and then in the HTML JavaScript use the window.dialogArguments to get a working COM Interface (IDispatch) for JavaScript. I could NOT find any JavaScript code that does this, or even mentions a method for this. But there may be one? The only way that I know to get a working COM Interface variable in javaScript is with some kind of "ActiveX" object creation. One way to do this in HTML is -

<OBJECT ID="MyInterface" width=0 height=0
 CLASSID="CLSID:D45FD81B-5C2E-11D1-9EC8-00C04FD1081F"
 CODEBASE="#VERSION=1,0,0,0">
</OBJECT>

  CLASSID="CLSID:YourInterfaceGUID"

reference of the HTML Object. I can not explain the complex workings of the Delphi COM Inteface creation and methods code here, I just mention this to let you know of the posibility for interaction between the HTML dialog and your program.